Date 函数
描述:返回当前系统日期。
语法:Date

DateAdd 函数
描述:返回已添加指定时间间隔的日期。
语法:DateAdd(interval, number, date)
interval: 必选。字符串表达式，表示要添加的时间间隔。有关数值，请参阅“设置”部分。
number: 必选。数值表达式，表示要添加的时间间隔的个数。数值表达式可以是正数（得到未来的日期）或负数（得到过去的日期）。
date: 必选。Variant 或要添加 interval 的表示日期的文字。 
interval 参数可以有以下值：
yyyy (年) 、q (季度) 、m (月) 、y (一年的日数) 、d (日) 、w (一周的日数) 、ww (周) 、h (小时) 、n (分钟) 、s (秒)
说明:可用 DateAdd 函数从日期中添加或减去指定时间间隔。例如可以使用 DateAdd 从当天算起 30 天以后的日期或从现在算起 45 分钟以后的时间。要向 date 添加以“日”为单位的时间间隔，可以使用“一年的日数”（“y”）、“日”（“d”）或“一周的日数”（“w”）。
DateAdd 函数不会返回无效日期。如下示例将 95 年 1 月 31 日加上一个月：
NewDate = DateAdd("m", 1, "31-Jan-95")
在这个例子中，DateAdd 返回 95 年 2 月 28 日，而不是 95 年 2 月 31 日。如果 date 为 96 年 1 月 31 日，则返回 96 年 2 月 29 日，这是因为 1996 是闰年。
如果计算的日期是在公元 100 年之前则会产生错误。
如果 number 不是 Long 型值，则在计算前四舍五入为最接近的整数。

DateDiff 函数
描述:返回两个日期之间的时间间隔。
语法:DateDiff(interval, date1, date2 [,firstdayofweek[, firstweekofyear>)
interval: 必选。字符串表达式，表示用于计算 date1 和 date2 之间的时间间隔。有关数值，请参阅“设置”部分。
date1, date2: 必选。日期表达式。用于计算的两个日期。
firstdayofweek: 可选。指定星期中第一天的常数。如果没有指定，则默认为星期日。有关数值，请参阅“设置”部分。
firstweekofyear: 可选。指定一年中第一周的常数。如果没有指定，则默认为 1 月 1 日所在的星期。有关数值，请参阅“设置”部分。
interval 参数可以有以下值：
yyyy (年) 、q (季度) 、m (月) 、y (一年的日数) 、d (日) 、w (一周的日数) 、ww (周) 、h (小时) 、n (分钟) 、s (秒)
firstdayofweek 参数可以有以下值：
(以下分别为：常数 值 描述)
vbUseSystem 0 使用区域语言支持 (NLS) API 设置。
vbSunday 1 星期日（默认）
vbMonday 2 星期一
vbTuesday 3 星期二
vbWednesday 4 星期三
vbThursday 5 星期四
vbFriday 6 星期五
vbSaturday 7 星期六
firstweekofyear 参数可以有以下值：
(以下分别为：常数 值 描述)
vbUseSystem 0 使用区域语言支持 (NLS) API 设置。
vbFirstJan1 1 由 1 月 1 日所在的星期开始（默认）。
vbFirstFourDays 2 由在新年中至少有四天的第一周开始。
vbFirstFullWeek 3 由在新的一年中第一个完整的周开始。
说明:DateDiff 函数用于判断在两个日期之间存在的指定时间间隔的数目。例如可以使用 DateDiff 计算两个日期相差的天数，或者当天到当年最后一天之间的星期数。
要计算 date1 和 date2 相差的天数，可以使用“一年的日数”（“y”）或“日”（“d”）。当 interval 为“一周的日数”（“w”）时，DateDiff 返回两个日期之间的星期数。如果 date1 是星期一，则 DateDiff 计算到 date2 之前星期一的数目。此结果包含 date2 而不包含 date1。如果 interval 是“周”（“ww”），则 DateDiff 函数返回日历表中两个日期之间的星期数。函数计算 date1 和 date2 之间星期日的数目。如果 date2 是星期日，DateDiff 将计算 date2，但即使 date1 是星期日，也不会计算 date1。
如果 date1 晚于 date2，则 DateDiff 函数返回负数。
firstdayofweek 参数会对使用“w”和“ww”间隔符号的计算产生影响。
如果 date1 或 date2 是日期文字，则指定的年度会成为日期的固定部分。但是如果 date1 或 date2 被包括在引号 (" ") 中并且省略年份，则在代码中每次计算 date1 或 date2 表达式时，将插入当前年份。这样就可以编写适用于不同年份的程序代码。
在 interval 为“年”（“yyyy”）时，比较 12 月 31 日和来年的 1 月 1 日，虽然实际上只相差一天，DateDiff 返回 1 表示相差一个年份。

DatePart 函数
描述:返回给定日期的指定部分。
语法:DatePart(interval, date[, firstdayofweek[, firstweekofyear>)
DatePart: 函数的语法有以下参数：
interval: 必选。字符串表达式，表示要返回的时间间隔。有关数值，请参阅“设置”部分。
date: 必选。要计算的日期表达式。
firstdayof week: 可选。指定星期中的第一天的常数。如果没有指定，则默认为星期日。有关数值，请参阅“设置”部分。
firstweekofyear: 可选。指定一年中第一周的常数。如果没有指定，则默认为 1 月 1 日所在的星期。有关数值，请参阅“设置”部分。
interval 参数可以有以下值：
yyyy (年) 、q (季度) 、m (月) 、y (一年的日数) 、d (日) 、w (一周的日数) 、ww (周) 、h (小时) 、n (分钟) 、s (秒)
firstdayofweek 参数可以有以下值：
(以下分别为：常数 值 描述)
vbUseSystem 0 使用区域语言支持 (NLS) API 设置。
vbSunday 1 星期日（默认）
vbMonday 2 星期一
vbTuesday 3 星期二
vbWednesday 4 星期三
vbThursday 5 星期四
vbFriday 6 星期五
vbSaturday 7 星期六
firstweekofyear 参数可以有以下值：
(以下分别为：常数 值 描述)
vbUseSystem 0 使用区域语言支持 (NLS) API 设置。
vbFirstJan1 1 由 1 月 1 日所在的星期开始（默认）。
vbFirstFourDays 2 由在新年中至少有四天的第一周开始。
vbFirstFullWeek 3 由在新的一年中第一个完整的周（不跨年度）开始。
说明:DatePart 函数用于计算日期并返回指定的时间间隔。例如使用 DatePart 计算某一天是星期几或当前的时间。
firstdayofweek 参数会影响使用“w”和“ww”间隔符号的计算。
如果 date 是日期文字，则指定的年度会成为日期的固定部分。但是如果 date 被包含在引号 (" ") 中，并且省略年份，则在代码中每次计算 date 表达式时，将插入当前年份。这样就可以编写适用于不同年份的程序代码。

DateSerial 函数
描述:对于指定的年、月、日，返回 Date 子类型的 Variant。
语法:DateSerial(year, month, day)
year: 从 100 到 9999 之间的数字或数值表达式。
month: 任意数值表达式。
day: 任意数值表达式。
说明:要指定日期，如 1991 年 12 月 31 日，DateSerial 函数中每个参数的取值范围都应该是可接受的；即日的取值应在 1 和 31 之间，月的取值应在 1 和 12 之间。但是，也可以使用表示某日之前或之后的年、月、日数目的数值表达式为每个参数指定相对日期。
以下样例中使用了数值表达式代替绝对日期。在这里，DateSerial 函数返回 1990 年 8 月 1 日之前十年 (1990 - 10) 零两个月 (8 - 2) 又一天 (1 - 1) 的日期：即 1980 年 5 月 31 日。
DateSerial(1990 - 10, 8 - 2, 1 - 1)
对于 year 参数，若取值范围是从 0 到 99，则被解释为 1900 到 1999 年。对于此范围之外的 year 参数，则使用四位数字表示年份（例如 1800 年）。
当任何一个参数的取值超出可接受的范围时，则会适当地进位到下一个较大的时间单位。例如，如果指定了 35 天，则这个天数被解释成一个月加上多出来的日数，多出来的日数取决于其年份和月份。但是如果参数值超出 -32,768 到 32,767 的范围，或者由三个参数指定（无论是直接还是通过表达式指定）的日期超出了可以接受的日期范围，就会发生错误。

DateValue 函数
描述:返回 Date 子类型的 Variant。
语法:DateValue(date)
date 参数应是字符串表达式，表示从 100 年 1 月 1 日到 9999 年 12 月 31 日中的一个日期。但是，date 也可以是表示上述范围内的日期、时间或日期时间混合的任意表达式。
说明:如果 date 参数包含时间信息，则 DateValue 不会返回时间信息。但是如果 date 包含无效的时间信息（如 "89:98"），就会出现错误。
如果 date 是某一字符串，其中仅包含由有效的日期分隔符分隔开的数字，则 DateValue 将会根据为系统指定的短日期格式识别月、日和年的顺序。DateValue 还会识别包含月份名称（无论是全名还是缩写）的明确日期。例如，除了能够识别 12/30/1991 和 12/30/91 之外，DateValue 还能识别 December 30, 1991 和 Dec 30, 1991。
如果省略了 date 的年份部分，DateValue 将使用计算机系统日期中的当前年份。

Day 函数
描述:返回 1 到 31 之间的一个整数（包括 1 和31），代表某月中的一天。
语法:Day(date)
date 参数是任意可以代表日期的表达式。如果 date 参数中包含 Null，则返回 Null。

FormatDateTime 函数
描述:返回表达式，此表达式已被格式化为日期或时间。
语法:FormatDateTime(Date[,NamedFormat])
Date: 必选。要被格式化的日期表达式。
NamedFormat: 可选。指示所使用的日期/时间格式的数值，如果省略，则使用 vbGeneralDate。
NamedFormat 参数可以有以下值：
(以下分别为：常数 值 描述)
vbGeneralDate 0 显示日期和/或时间。如果有日期部分，则将该部分显示为短日期格式。如果有时间部分，则将该部分显示为长时间格式。如果都存在，则显示所有部分。 
vbLongDate 1 使用计算机区域设置中指定的长日期格式显示日期。
vbShortDate 2 使用计算机区域设置中指定的短日期格式显示日期。
vbLongTime 3 使用计算机区域设置中指定的时间格式显示时间。
vbShortTime 4 使用 24 小时格式 (hh:mm) 显示时间。

Hour 函数
描述:返回 0 到 23 之间的一个整数（包括 0 和 23），代表一天中的某一小时。
语法:Hour(time)
time 参数是任意可以代表时间的表达式。如果 time 参数中包含 Null，则返回 Null。

Minute 函数
描述:返回 0 到 59 之间的一个整数（包括 0 和59），代表一小时内的某一分钟。
语法:Minute(time)
time 参数是任意可以代表时间的表达式。如果 time 参数包含 Null，则返回 Null。

Month 函数
描述:返回 1 到 12 之间的一个整数（包括 1 和 12），代表一年中的某月。
语法:Month(date)
date 参数是任意可以代表日期的表达式。如果 date 参数中包含 Null，则返回 Null。

MonthName 函数
描述:返回表明指定月份的字符串。
语法:MonthName(month[, abbreviate])
month: 必选。月份的数值定义。例如，一月是 1，二月是 2，以此类推。
abbreviate: 可选。Boolean 值，表明月份名称是否简写。如果省略，默认值为 False，即不简写月份名称。

Now 函数
描述:根据计算机系统设定的日期和时间返回当前的日期和时间值。
语法:Now

Second 函数
描述:返回 0 到 59 之间的一个整数（包括 1 和 59），代表一分钟内的某一秒。
语法:Second(time)
time 参数是任意可以代表时间的表达式。如果 time 参数中包含 Null，则返回 Null。

Time 函数
描述:返回 Date 子类型 Variant，指示当前系统时间。
语法:Time

TimeSerial 函数
描述:返回一个 Date 子类型的 Variant，含有指定时、分、秒的时间。
语法:TimeSerial(hour, minute, second)
hour: 其值为从 0 (12:00 A.M.) 到 23 (11:00 P.M.) 的数值或数值表达式。
minute: 任意数值表达式。
second: 任意数值表达式。
说明:要指定一时刻，如 11:59:59，TimeSerial 的参数取值应在可接受的范围内；也就是说，小时应介于 0-23 之间，分和秒应介于 0-59 之间。但是，可以使用数值表达式为每个参数指定相对时间，这一表达式代表某时刻之前或之后的时、分或秒数。以下样例中使用了表达式代替绝对时间数。TimeSerial 函数返回中午之前六小时 (12 - 6) 十五分钟的时间 (-15)，即 5:45:00 A.M.。
TimeSerial(12 - 6, -15, 0)
当任何一个参数的取值超出可接受的范围时，它会正确地进位到下一个较大的时间单位中。例如，如果指定了 75 分钟，则这个时间被解释成一小时十五分钟。但是，如果任何一个参数值超出 -32768 到 32767 的范围，就会导致错误。如果使用三个参数直接指定的时间或通过表达式计算出的时间超出可接受的日期范围，也会导致错误。

TimeValue 函数
描述:返回包含时间的 Date 子类型的 Variant。
语法:TimeValue(time)
time 参数通常是代表从 0:00:00 (12:00:00 A.M.) 到 23:59:59 (11:59:59 P.M.) 的字符串表达式（包括 0:00:00 和 23:59:59）。不过，time 也可以是代表该范围内任何时间的表达式。如果 time 参数包含 Null，则返回 Null。
说明:可以采用 12 或 24 小时时钟格式输入时间。例如 "2:24PM" 和 "14:24" 都是有效的 time 参数。
如果 time 参数包含日期信息， TimeValue 函数并不返回日期信息。然而，如果 time 参数包含无效的日期信息，则会出现错误。

Weekday 函数
描述:返回代表一星期中某天的整数。
语法:Weekday(date, [firstdayofweek])
date: 可以代表日期的任意表达式。如果 date 参数中包含 Null，则返回 Null。
firstdayofweek: 指定星期中第一天的常数。如果省略，默认使用 vbSunday。
firstdayofweek 参数有如下设置：
(以下分别为：常数 值 描述)
vbUseSystem 0 使用区域语言支持 (NLS) API 设置。
vbSunday 1 星期日
vbMonday 2 星期一
vbTuesday 3 星期二
vbWednesday 4 星期三
vbThursday 5 星期四
vbFriday 6 星期五
vbSaturday 7 星期六
Weekday 函数返回如下值：
(以下分别为：常数 值 描述)
vbSunday 1 星期日
vbMonday 2 星期一
vbTuesday 3 星期二
vbWednesday 4 星期三
vbThursday 5 星期四
vbFriday 6 星期五
vbSaturday 7 星期六

WeekdayName 函数
描述:返回一个字符串，表示星期中指定的某一天。
语法:WeekDayName(weekday, abbreviate, firstdayofweek)
weekday: 必选。星期中某天的数值定义。各天的数值定义取决于 firstdayofweek 参数设置。
abbreviate: 可选。Boolean 值，指明是否缩写表示星期各天的名称。如果省略， 默认值为 False，即不缩写星期各天的名称。
firstdayofweek: 可选。指明星期第一天的数值。关于数值，请参阅“设置”部分。
firstdayofweek 参数有以下值：
(以下分别为：常数 值 描述)
vbUseSystem 0 使用区域语言支持 (NLS) API 设置。
vbSunday 1 星期日（默认）
vbMonday 2 星期一
vbTuesday 3 星期二
vbWednesday 4 星期三
vbThursday 5 星期四
vbFriday 6 星期五
vbSaturday 7 星期六

Year 函数
描述:返回一个代表某年的整数。
语法:Year(date)
date 参数是任意可以代表日期的参数。如果 date 参数中包含 Null，则返回 Null。

一、Asp基本知识

1．Asp是Active Server Pages的简称，是解释型的脚本语言环境；
2．Asp的运行需要Windows操作系统，9x下需要安装PWS；而NT/2000/XP则需要安装Internet Information Server（简称IIS）；
3．Asp和JSP的脚本标签是“<%%>”，PHP的则可以设定为多种；
4．Asp的注释符号是“'”；
5.使用附加组件，可以扩展Asp的功能。
from www。11111。com

例子：

HelloWorld_1.asp
<%="Hello,world"%>

效果：
Hello,world

HelloWorld_2.asp
<%
for i=1 to 10
response.write "Hello,world"
next
%>

效果：
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world
Hello,world

注意：Asp不区分大小写；变量无需定义也可使用，转换方便；语法检查很松。

二、Asp内置对象的使用：

可以使用下面的任何ASP内置对象，而不必在ASP脚本中特别声明。

1．    Request：

定义：可用来访问从浏览器发送到服务器的请求信息，可用此对象读取已输入HTML表单的信息。

集：
Cookies：含有浏览器cookies的值
Form：含有HTML表单域中的值
QueryString：含有查询字符串的值
ServerVariables：含有头和环境变量中的值

例子：

request_url.asp
<%
'获取用户输入，并存入变量
user_id=request.querystring("user_id")
user_name=request.querystring("user_name")

'判断用户输入是否正确
if user_id="" then
response.write "User_id is null,please check it"
response.end
end if
if user_name="" then
response.write "User_name is null,please check it"
response.end
end if

'打印变量
response.write user_id&"<br>"
response.write user_name
%>

效果：
当访问request_url.asp?user_name=j时：
User_id is null,please check it
当访问request_url.asp?user_name=j&;user_id=my_id时：
my_id
j

思考：变量是如何在URL中传递和被Asp页面获取的？

request_form.htm
<style type="text/css">
<!--
.input {background-color: #FFFFFF; border-bottom: black 1px solid;border-left: black 1px solid; border-right: black 1px solid;border-top: black 1px solid; color: #000000;font-family: Georgia; font-size: 9pt;color: midnightblue;}
a:link {color: #1B629C; text-decoration: none}
a:hover {color: #FF6600; text-decoration: underline}
a:visited {text-decoration: none}
-->
</style>

<center>
<form name="course" action="request_form.asp" method="post">
User_id：<input type="text" name="user_id" maxlength="20" class="input"><br><br>
User_name：<input type="text" name="user_name" maxlength="30" class="input">
</form>
<br><br>
<a href="javascript :document.course.submit();"> 提 交 </a>
</center>

request_form.asp
<%
'获取用户输入，并存入变量
user_id=request.form("user_id")
user_name=request.form("user_name")

'判断用户输入是否正确
if user_id="" then
response.write "User_id is null,please check it"
response.end
end if
if user_name="" then
response.write "User_name is null,please check it"
response.end
end if

'打印变量
response.write user_id&"<br>"
response.write user_name
%>

注意：form的action的指向，request_form.asp和request_url.asp在源代码上的区别？

2．    Response：

定义：用来向浏览器回发信息，可用此对象从脚本向浏览器发送输出。

集：
Cookies：在浏览器中加入一个cookie

方法：
End：结束脚本的处理
Redirect：将浏览器引导至新页面
Write：向浏览器发送一个字符串

属性：
Buffer：缓存一个ASP
CacheControl：由代理服务器控制缓存
ContentType： 规定响应的内容类型
Expires：浏览器用相对时间控制缓存
ExpiresAbsolute：浏览器用绝对时间控制缓存

例子：

response_redirect.asp
<%
'去google看看吧
response.redirect "http://....."
response.end
%>

response_cookies.asp
<%
'设置和读取cookies
response.cookies("time_now")=now()
response.write request.cookies("time_now")
%>

效果：
当访问response_cookies.asp时：
2002-9-1 16:20:40

response_buffer.asp
<%'response.buffer=true%>
<a href="a">a</a>
<%response.redirect "request_form.htm"%>

效果：
①．当关闭IIS的缓冲功能，访问该页面时出错
a
答复对象 错误 'ASP 0156 : 80004005'
头错
/course/response_buffer.asp，行3
HTTP 头已经写入到 客户浏览器。任何 HTTP 头的修改必须在写入页内容之前。
②．当关闭IIS的缓冲功能，去掉文件第一行的注释，则页面重定向成功
③．当打开IIS的缓冲功能，无论是否去掉文件第一行的注释，页面重定向都成功

3．    Server

定义：可在服务器上使用不同实体函数，如在时间到达前控制脚本执行的时间。还可用来创建其他对象。

方法：
CreateObject：创建一个对象实例
HTMLEncode：将字符串转化为使用特别的HTML字符
MapPath：把虚拟路径转化成物理路径
URLEncode：把字符串转化成URL编码的
ScriptTimeout：在终止前，一个脚本允许运行的秒数

例子：

server_htmlencode.asp
<%
'html encode
response.write server.htmlencode("a""time_now")
%>

效果：
a"time_now
查看源文件时显示为：a"time_now

思考：为什么不是a""time_now这种效果？源文件是怎么了？

server_mappath.asp
<%
'mappath
response.write server.mappath("server_mappath.asp")
%>

效果：
G:\asp_www\test\course\server_mappath.asp

思考：如何获取站点根目录的实际路径？如何获取某个目录的实际路径？

server_urlencode.asp
<%
'url encode
response.write server.urlencode("a\time_now")
%>

效果：
a%5Ctime%5Fnow

4．    Application

定义：用来存储、读取用户共享的应用程序信息，如可以用此对象在网站的用户间传送信息，当服务器重启后信息丢失。

方法：
Lock：防止其它用户访问Application集
Unlock：使其它用户可以访问Application集

事件：
OnEnd：由终止网络服务器、改变Global.asa文件触发
OnStart：由应用程序中对网页的第一次申请触发

例子：

application_counter.asp
<%
'一个使用Application制作的简单计数器
Application.lock
Application("clicks")=Application("clicks")+1
Application.unlock

response.write "您是本站第 "&Application("clicks")&" 位访客！"
response.write "<br><br>您来自 "&request.servervariables("remote_addr")
%>

效果：
您是本站第 1 位访客！

您来自 10.1.43.238

思考：本例中lock和unlock有何作用？

5．    Session

定义：存储、读取特定用户对话信息，如可存储用户对网站的访问信息，当服务器重启后信息丢失。

方法：
Abandon：处理完当前页面后，结束一个用户会话

属性：
Timeout：用户会话持续时间（分钟数）

事件：
OnEnd：在Session Timeout时间以外，用户不再申请页面触发该事件
OnStart：由用户对网页的第一次申请时触发

例子：

session_counter.asp
<%
'一个使用Session制作的简单计数器
session("clicks")=session("clicks")+1

response.write "您是本站第 "&session("clicks")&" 位访客！"
response.write "<br><br>您来自 "&request.servervariables("remote_addr")
%>

效果：
您是本站第 1 位访客！

您来自 10.1.43.238

思考：既然session和application都能做到计数，那它们之间有什么区别？如果要做到满100重新开始计数如何实现？

三、使用Asp操作数据库：

1．通过ODBC或者OLE方式连接的区别？

现在有两种连接数据库的方法。一方面，可以用ODBC产生一个连接，这种连接与任何有ODBC驱动器的数据库（即基本上是市场上所有的数据库）兼容；另一方面，可以用原始OLE DB提供商产生一个连接。

该用哪个提供商？尽可能用原始OLE DB提供商，因为它提供了对数据更有效的访问。Microsoft正逐步用OLE DB取代ODBC标准，应该仅仅在没有原始OLE DB提供商时使用ODBC。

⑴．用ODBC方式连接SQL Server：
①．配置ODBC
②．连接代码：
conn_odbc.asp
<%
Set Conn = Server.CreateObject("ADODB.Connection")
'Conn.Open "DSN=course_dsn;UID=course_user;PWD=course_password;DATABASE=course"
Conn.Open "course_dsn","course_user","course_password"
%>
注意：在配置MyDSN时若指定默认数据库为course则上述代码作用想同，否则第二行的连接方式更有灵活性，可以指定连接某个数据库（当然，前提是course_user对这个数据库有操作权限）。

    ⑵．用OLE方式连接SQL Server：
    conn_ole.asp
<%
Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open "PROVIDER=SQLOLEDB;DATA SOURCE=10.1.43.238,2433; UID=course_user;PWD=course_password;DATABASE=course"
%>

2．操作数据库：Connection和Recordset

联合使用connection和recordset操作数据库，或者只使用connection操作数据库。

例子：

⑴．联合使用connection和recordset操作数据库

use_db_1.asp
<%
Set conn=Server.CreateObject("ADODB.Connection")    '创建连接数据库的对象
conn.Open "course_dsn","course_user","course_password"    '使用该对象连接数据库
Set rs=Server.CreateObject("ADODB.RecordSet")            '创建记录集对象
rs.Open "select * from user_info",conn,1,1                '使用记录集对象打开数据库
if rs.recordcount>0 then                                '如果有记录
response.write "User_id  User_name<br>"
for i=1 to rs.recordcount                                '循环读取所有纪录
response.write rs("id")&"        "&rs("user_name")&"<br>"
'向浏览器输出纪录的字段
rs.movenext                                                '指针下移一行
if rs.eof then exit for                                '如果到达记录集底部则退出循环
next
end if
%>

效果：
User_id  User_name
1        ahyi
3        test

⑵．只使用connection操作数据库：

use_db_2.asp
<%
Set conn=Server.CreateObject("ADODB.Connection")    '创建连接数据库的对象
conn.Open "course_dsn","course_user","course_password"    '使用该对象连接数据库
conn.execute "delete from user_info"
%>

效果：
user_info表中所有数据被删除

思考：两种方式有和区别？各应用于什么场合？

3．如何使用事务处理、存储过程和视图？

⑴．使用存储过程

    ①．定义好存储过程

CREATE PROCEDURE [output_1]
@sid int output
AS
set @sid=2

CREATE PROCEDURE [return_1]
(@user_name varchar(40),@password varchar(20))
AS
if exists(select id from user_info where user_name=@user_name and password=@password)
return 1
else
return 0

CREATE PROCEDURE [user_info_1]
(@user_name varchar(40),@password varchar(20))
AS
select id from user_info where user_name=@user_name and password=@password

CREATE PROCEDURE [user_info_2]
(@user_name varchar(40),@password varchar(20))
AS
SET XACT_ABORT ON
BEGIN TRANSACTION
delete from user_info where user_name=@user_name and password=@password
COMMIT TRANSACTION
SET XACT_ABORT OFF

CREATE PROCEDURE [user_info_3] AS
select * from user_info

    ②．在Asp中调用

use_proc.asp
<!-- #include virtual="/adovbs.inc" -->
<%
Set conn=Server.CreateObject("ADODB.Connection")
conn.Open "course_dsn","course_user","course_password"

'使用recordset调用带两个输入参数和返回纪录集的存储过程
'CREATE PROCEDURE [user_info_1]
'(@user_name varchar(40),@password varchar(20))
'AS
'select id from user_info where user_name=@user_name and password=@password
response.write "普通的调用方法：<br>"
set rs=server.createobject("adodb.recordset")
sql="user_info_1 '"&request.querystring("user_name")&"','"&request.querystring("password")&"'"
rs.open sql,conn,1,1
response.write rs("id")&"<br>"
rs.close

'使用recordset调用无输入参数，返回纪录集的存储过程，可以使用recordcount等属性
'CREATE PROCEDURE [user_info_3] AS
'select * from user_info
response.write "<br>返回纪录集，可以使用recordcount等属性："
sql="exec user_info_3"
rs.open sql,conn,1,1
for i=1 to rs.recordcount
response.write "<br>"&rs("user_name")
rs.movenext
next
rs.close
set rs=nothing

'使用command调用带输出参数的存储过程
'CREATE PROCEDURE [output_1]
'@sid int output
'AS
'set @sid=2
response.write "<br><br>调用带输出参数的存储过程：<br>"
set cmd=server.createobject("adodb.command")
cmd.activeconnection=conn
cmd.commandtext = "output_1"
cmd.parameters.append cmd.createparameter("@sid",adinteger,adparamoutput)
cmd("@sid")=10
cmd.execute()
bbb=cmd("@sid")
response.write bbb&"<br>"
set cmd=nothing

'使用command调用带两个输入参数和返回值的存储过程
'CREATE PROCEDURE [return_1]
'(@user_name varchar(40))
'AS
'if exists(select id from user_info where user_name=@user_name)
'return 1
'else
'return 0
response.write "<br>调用带两个输入参数和返回值的存储过程：<br>"
set cmd=server.createobject("adodb.command")
cmd.activeconnection=conn
cmd.commandtype = adcmdstoredproc
cmd.commandtext = "return_1"
cmd.parameters.append cmd.createparameter("@return_value",adinteger,adparamreturnvalue)
cmd.parameters.append cmd.createparameter("@user_name",advarchar,adparaminput,40)
cmd.parameters.append cmd.createparameter("@password",advarchar,adparaminput,20)
cmd("@user_name")="tuth"
cmd("@password")="yyuyu"
cmd.execute()
rrr=cmd("@return_value")
response.write rrr
set cmd=nothing

conn.close
set conn=nothing
%>

    效果：
访问use_proc.asp?user_name=ahyi&;password=ttt时，出现如下

普通的调用方法：
12

返回纪录集，可以使用recordcount等属性：
ahyi
tet
tuth

调用带输出参数的存储过程：
2

调用带两个输入参数和返回值的存储过程：
1

注意：若存储过程无参数，则调用的sql语句直接为存储过程名，一个参数为“存储过程名 参数”，若是多个参数，则“存储过程名 参数1，参数2，……，参数n”；如果在sql语句中加入exec，则在返回的记录集中可以使用recordcount等属性；如果想获得存储过程的返回值或输出参数，可以使用command对象。

⑵．使用事务处理

①．Asp内嵌的事务支持

例子：
use_transaction_1.asp
<%
'Asp中使用事务
Set conn=Server.CreateObject("ADODB.Connection")
conn.Open "course_dsn","course_user","course_password"
conn.begintrans        '开始事务

sql="delete from user_info"
set rs=server.createobject("adodb.recordset")
rs.open sql,conn,3,3
if conn.errors.count>0 then        '有错误发生
conn.rollbacktrans                '回滚
set rs=nothing
conn.close
set conn=nothing
response.write "交易失败，回滚至修改前的状态！"
response.end
else
conn.committrans                '提交事务
set rs=nothing
conn.close
set conn=nothing
response.write "交易成功！"
response.end
end if
%>

②．数据库级的事务

    i．创建存储过程

CREATE PROCEDURE [user_info_2]
(@user_name varchar(40),@password varchar(20))
AS
SET XACT_ABORT ON
BEGIN TRANSACTION
delete from user_info where user_name=@user_name and password=@password
COMMIT TRANSACTION
SET XACT_ABORT OFF

    ii．在Asp中调用

use_transaction_2.asp
<%
Set conn=Server.CreateObject("ADODB.Connection")
conn.Open "course_dsn","course_user","course_password"

sql="user_info_2 '"&request.querystring("user_name")&"','"&request.querystring("password")&"'"

set rs=server.createobject("adodb.recordset")
rs.open sql,conn,1,1
set rs=nothing
conn.close
set conn=nothing
%>
   
讨论：两种方式的优劣？

⑶．使用视图
    在数据库中定义好视图之后，在Asp中如同使用一个表一样来使用视图

4．一个数据库分页的例子

db_page.asp
<%
on error resume next
Set conn=Server.CreateObject("ADODB.Connection")    '创建连接数据库的对象
conn.Open "course_dsn","course_user","course_password"    '使用该对象连接数据库
set rs=server.createObject("adodb.recordset")
sql="select * from user_info order by id desc"
rs.open sql,conn,1,1

if rs.recordcount>0 then        '如果有记录
    rs.pagesize=2                '每页最多显示2条纪录
    '从URL获取当前要显示的页
    page=cint(request("page"))
    '页面参数异常处理
    if page="" then page=1
    if page<1 then page=1
    if page>= rs.pagecount then page=rs.pagecount
    rs.absolutepage=page        '当前页为page参数指定的页
    for i=1 to rs.pagesize        '根据pagesize参数的大小循环显示当前页中的纪录
        response.write "User_id："&rs("id")&"<br>"
        response.write "User_name："&rs("user_name")&"<br><br>"
        rs.movenext                '纪录指针下移
        if rs.eof then exit for    '如果到达纪录集底部则退出循环
    next
end if

'显示翻页按钮
if page>1 then
    response.write "<a href="&request.servervariables("document_name")&"?page=1>第一页</a>　"
    response.write "<a href="&request.servervariables("document_name")&"?page="&(page-1)&">上一页</a>　"
end if
if page<>rs.pagecount then
    response.write "<a href="&request.servervariables("document_name")&"?page="&(page+1)&">下一页</a>　"
    response.write "<a href="&request.servervariables("document_name")&"?page="&rs.pagecount&">最后一页</a>　"
end if
response.write"页码："&page&"/"&rs.pagecount

'关闭对象，释放内存
rs.close
set rs=nothing
conn.close
set conn=nothing
%>